import io.papermc.paperweight.userdev.ReobfArtifactConfiguration
import net.minecrell.pluginyml.paper.PaperPluginDescription

group = "net.hareworks"
version = "1.0"

plugins {
    kotlin("jvm") version "2.3.21"
    id("de.eldoria.plugin-yml.paper") version "0.9.0"
    id("com.gradleup.shadow") version "9.2.2"
    id("io.papermc.paperweight.userdev") version "2.0.0-beta.21"
}
repositories {
    mavenCentral()
    maven("https://repo.papermc.io/repository/maven-public/")
    maven("https://repo.extendedclip.com/content/repositories/placeholderapi/")
}

paperweight.reobfArtifactConfiguration = ReobfArtifactConfiguration.MOJANG_PRODUCTION

dependencies {
    compileOnly("me.clip:placeholderapi:2.11.6")
    paperweight.paperDevBundle("26.1.2.build.49-beta")
    compileOnly("org.jetbrains.kotlin:kotlin-stdlib:2.1.0")
    implementation("net.hareworks:kommand-lib:1.1")
    implementation("net.hareworks:permits-lib:1.1")
    compileOnly("net.kyori:adventure-text-minimessage:4.26.1")
    compileOnly("net.kyori:adventure-text-serializer-plain:4.26.1")
}

kotlin {
    jvmToolchain(25)
}

paper {
    main = "net.hareworks.ghostdisplays.GhostDisplaysPlugin"
    name = "GhostDisplays"
    version = project.version as String
    apiVersion = "26.1"
    foliaSupported = true
    description = "Invisible display entity controller library."
    authors = listOf("Hareworks")
    serverDependencies {
        register("PlaceholderAPI") {
            required = false
            load = PaperPluginDescription.RelativeLoadOrder.BEFORE
        }
        register("hcu-core") {
            required = true
            load = PaperPluginDescription.RelativeLoadOrder.BEFORE
        }
    }
}
tasks {
    withType<Jar> {
        archiveBaseName.set("GhostDisplays")
    }
    shadowJar {
        archiveClassifier.set("min")
        minimize {
            exclude(dependency("net.hareworks:kommand-lib"))
            exclude(dependency("net.hareworks:permits-lib"))
            exclude(dependency("org.jetbrains.kotlin:kotlin-stdlib"))
            exclude(dependency("org.jetbrains.kotlin:kotlin-reflect"))
            exclude(dependency("org.jetbrains.kotlin:kotlin-stdlib-jdk8"))
            exclude(dependency("org.jetbrains.kotlin:kotlin-stdlib-jdk7"))
        }
    }
}