import net.minecrell.pluginyml.paper.PaperPluginDescription

group = "net.hareworks"
version = "1.0"

plugins {
    kotlin("jvm") version "2.2.21"
    id("de.eldoria.plugin-yml.paper") version "0.8.0"
    id("com.gradleup.shadow") version "9.2.2"
}
repositories {
    mavenCentral()
    maven("https://repo.papermc.io/repository/maven-public/")
    maven("https://repo.extendedclip.com/content/repositories/placeholderapi/")
}

dependencies {
    compileOnly("me.clip:placeholderapi:2.11.6")
    compileOnly("io.papermc.paper:paper-api:1.21.10-R0.1-SNAPSHOT")
    paperLibrary("org.jetbrains.kotlin:kotlin-stdlib:2.1.0")
    implementation("net.hareworks:kommand-lib:1.1")
    implementation("net.hareworks:permits-lib:1.1")
    compileOnly("net.kyori:adventure-text-minimessage:4.17.0")
    compileOnly("net.kyori:adventure-text-serializer-plain:4.17.0")
}

kotlin {
    jvmToolchain(21)
}

paper {
    main = "net.hareworks.ghostdisplays.GhostDisplaysPlugin"
    name = "GhostDisplays"
    version = project.version as String
    apiVersion = "1.21"
    description = "Invisible display entity controller library."
    authors = listOf("Hareworks")
    serverDependencies {
        register("PlaceholderAPI") {
            required = false
            load = PaperPluginDescription.RelativeLoadOrder.BEFORE
        }
    }
}
tasks {
    withType<Jar> {
        archiveBaseName.set("GhostDisplays")
    }
    shadowJar {
        archiveClassifier.set("min")
        minimize {
            exclude("net.hareworks:kommand-lib")
            exclude("net.hareworks:permits-lib")
        }
    }
}