import net.minecrell.pluginyml.paper.PaperPluginDescription

group = "net.hareworks"
version = "1.2"


plugins {
    kotlin("jvm") version "2.2.21"
    kotlin("plugin.serialization") version "2.2.21"
    id("de.eldoria.plugin-yml.paper") version "0.8.0"
    id("com.gradleup.shadow") version "9.2.2"
}
repositories {
    mavenCentral()
    maven("https://repo.papermc.io/repository/maven-public/")
    maven("https://repo.codemc.io/repository/maven-public/")
}

val exposedVersion = "0.54.0"
dependencies {
    compileOnly("io.papermc.paper:paper-api:1.21.10-R0.1-SNAPSHOT")
    compileOnly("org.jetbrains.kotlin:kotlin-stdlib")
    compileOnly("net.hareworks:kommand-lib:1.1")
    implementation("net.kyori:adventure-api:4.17.0")
    implementation("net.kyori:adventure-text-minimessage:4.17.0")
    implementation("org.jetbrains.kotlinx:kotlinx-serialization-json:1.7.1")
    implementation("org.postgresql:postgresql:42.7.1")
    implementation("org.jetbrains.exposed:exposed-core:$exposedVersion")
    implementation("org.jetbrains.exposed:exposed-dao:$exposedVersion")
    implementation("org.jetbrains.exposed:exposed-jdbc:$exposedVersion")
    implementation("org.jetbrains.kotlinx:kotlinx-datetime:0.6.1")
    implementation("org.jetbrains.exposed:exposed-kotlin-datetime:$exposedVersion")
    implementation("de.tr7zw:item-nbt-api:2.15.3")
}
tasks {
    withType<Jar> {
        archiveBaseName.set("SimplyMCDB")
    }
    shadowJar {
        minimize()
        archiveClassifier.set("min")
        relocate("de.tr7zw.changeme.nbtapi", "net.hareworks.simplymcdb.libs.nbtapi")
    }
}

paper {
    main = "net.hareworks.simplymcdb.App"
    name = "Simply-Minecraft-DB"
    description = "It provides a simple way to manage player data through a database."
    version = getVersion().toString()
	apiVersion = "1.21.10"
    authors = listOf(
        "Hare-K02"
    )
    serverDependencies {
        register("kommand-lib") {
            load = PaperPluginDescription.RelativeLoadOrder.BEFORE
        }
        register("permits-lib") {
            load = PaperPluginDescription.RelativeLoadOrder.BEFORE
        }
    }
}