import net.minecrell.pluginyml.paper.PaperPluginDescription

group = "net.hareworks.hcu"
version = "1.0"

plugins {
    kotlin("jvm") version "2.2.21"
    kotlin("plugin.serialization") version "2.2.21"
    id("de.eldoria.plugin-yml.paper") version "0.8.0"
    id("com.gradleup.shadow") version "9.2.2"
}
repositories {
    mavenCentral()
    maven("https://repo.papermc.io/repository/maven-public/")
}

val exposedVersion = "1.0.0-rc-4"

dependencies {
    compileOnly("io.papermc.paper:paper-api:1.21.10-R0.1-SNAPSHOT")
    compileOnly("org.jetbrains.kotlin:kotlin-stdlib:2.1.0")
    implementation("org.jetbrains.kotlinx:kotlinx-serialization-json:1.9.0") {
        exclude(group = "org.jetbrains.kotlin")
    }
    implementation("com.michael-bull.kotlin-result:kotlin-result:2.1.0")

    compileOnly("net.hareworks.hcu:hcu-core")
    implementation("net.hareworks:kommand-lib")
    implementation("net.hareworks:permits-lib")
    compileOnly("net.hareworks:GhostDisplays")
    
    implementation(project(":visualizer-lib"))

    compileOnly("net.kyori:adventure-api:4.25.0")
    compileOnly("net.kyori:adventure-text-minimessage:4.25.0")

    compileOnly("org.postgresql:postgresql:42.7.8")
    compileOnly("org.jetbrains.exposed:exposed-core:$exposedVersion")
    compileOnly("org.jetbrains.exposed:exposed-dao:$exposedVersion")
    compileOnly("org.jetbrains.exposed:exposed-jdbc:$exposedVersion")
    compileOnly("org.jetbrains.exposed:exposed-kotlin-datetime:$exposedVersion")
}
tasks {
    withType<Jar> {
        archiveBaseName.set("lands")
    }
    shadowJar {
        archiveClassifier.set("min")
        minimize {
            exclude(dependency("net.hareworks:GhostDisplays"))
            exclude(dependency("net.hareworks:kommand-lib"))
            exclude(dependency("net.hareworks:permits-lib"))
        }
        dependencies {
            exclude(dependency("org.jetbrains.kotlin:kotlin-stdlib"))
            exclude(dependency("org.jetbrains.kotlin:kotlin-reflect"))
            exclude(dependency("org.jetbrains.kotlin:kotlin-stdlib-jdk8"))
            exclude(dependency("org.jetbrains.kotlin:kotlin-stdlib-jdk7"))
        }

        relocate("net.hareworks.kommand_lib", "net.hareworks.hcu.lands.libs.kommand_lib")
        relocate("net.hareworks.permits_lib", "net.hareworks.hcu.lands.libs.permits_lib")
    }
}

paper {
    main = "net.hareworks.hcu.lands.App"
    name = "lands"
    description = "land plugin"
    version = getVersion().toString()
    apiVersion = "1.21.10"
    serverDependencies {
        register("hcu-core") {
            required = true
            load = PaperPluginDescription.RelativeLoadOrder.BEFORE
        }
        register("GhostDisplays") {
            required = true
            load = PaperPluginDescription.RelativeLoadOrder.BEFORE
        }
    }
    authors =
            listOf(
                "Hare-K02",
                "Kaariyaaa"
            )
}